******************************************************
* Model generated on 6 Jan 2010
* modified: 11 Feb 2010 (triode model where wired as triode, suffixed '_at')
* modified: 16 Aug 2010, correct for more realistic screen grid currents!
* Model format: LTspice
* New tetrodes macro model
* as by Norman L. Koren
* formulas @ http://www.normankoren.com/Audio/Tubemodspice_article.html
* External node designations
* Node A -> Anode
* Node S -> Screen
* Node G -> Grid
* Node K -> Cathode
*
* MU = amplification factor.
* EX = line curvature, typical range from 1.3 to 1.4, increases with EX.
* kG1 = used to fit the equation to data for anode current.
* kG2 = similar to kG1 for screen current (pentode).
* KP (kP) behaviour region (A) (large negative grid voltage,
* large plate voltage, and low plate current).
* KVB "knee" of the characteristic curves, for positive bias.

******************************************************
* NOTE for most of these kg2 was 4500, this makes for
* unrealistically small screen current! All changed to
* 1500, 14/08/2010


.subckt Tetrode A S G K ; = 6L6CG - base generic
+params: mu=8.7 ex=1.35 kg1=1460 kg2=1500 kp=48 kvb=12 ccg=14p cpg=0.85p ccp=12p rgi=1k

RE1   E1 0  1MEG ; dummy so node E1 has two connections
Ee1   E1 0  Value={(V(S,K)/kP) * log(1+exp(kP * (1/Mu+V(G,K)/V(S,K))))}
GIP   A  K  Value={(PWR(V(E1),EX)+PWRS(V(E1),EX))/KG1*ATAN(V(A,K)/KVB)}
GIG2  S  K  Value={(EXP(EX*(LOG((V(S,K)/MU)+V(G,K)))))/KG2}

* 'old' version:
* GIG2  S  K  Value={pwr((V(G,K)+V(S,K)/mu),1.5)/kG2}

R1    G  5  {rgi} ; for grid forward current
D3    5  K  DX ; for grid diode action
RZ    5  0  1G
CM1   G  K  {ccg}
CM2   A  G  {cpg}
CM3   A  K  {ccp}
RF1   A  0  1G ; }
RF2   S  0  1G ; } prevent floating nodes
RF3   G  0  1G ; }
RF4   K  0  1G ; } 
.MODEL DX D(Ron=1 Roff=1G Vfwd=.75)
.ends

.subckt Tetrode2 A S G K
* Only used by EF80 & EF85
RE1   E1 0  1MEG
Ee1   E1 0  Value={(V(S,K)/{kP}) * log(1+exp({kP} * (1/{Mu}+V(G,K)/V(S,K))))}
GIP   A  K  VALUE={pi/2*(PWR(V(E1),EX)+PWRS(V(E1),EX))/KG1*(1-exp(-2*V(A,K)/(pi*KVB)))}
GIG2  S  K  Value={(EXP(EX*(LOG((V(S,K)/MU)+V(G,K)))))/KG2}

R1    G  5  {rgi} ; for grid forward current
D3    5  K  DX ; for grid diode action
CM1   G  K  {ccg}
CM2   A  G  {cpg}
CM3   A  K  {ccp}
RF1   A  0  1G ; }
RF2   S  0  1G ; } prevent floating nodes
RF3   G  0  1G ; }
RF4   K  0  1G ; } 
.MODEL DX D(Ron=1 Roff=1G Vfwd=.75)
.ends

.subckt Tetrode3 A S G K
* ECF82 pentode only!
RE1   E1 0  1MEG
Ee1   E1 0  Value={(V(S,K)/{kP}) * log(1+exp({kP} * (1/{Mu}+V(G,K)/V(S,K))))}
GIP   A  K  VALUE={pi/2*(PWR(V(E1),EX)+PWRS(V(E1),EX))/KG1*tanh(2*V(A,K)/(pi*KVB))}
GIG2  S  K  Value={(EXP(EX*(LOG((V(S,K)/MU)+V(G,K)))))/KG2}
* GZ1   S  K  K  G  table=(0 6m, 1 3.5m, 2 2m, 3 1m, 4 0.5m)
RS1   S  K  200k

R1    G  5  {rgi} ; for grid forward current
D3    5  K  DX ; for grid diode action
CM1   G  K  {ccg}
CM2   A  G  {cpg}
CM3   A  K  {ccp}
RF1   A  0  1G ; }
RF2   S  0  1G ; } prevent floating nodes
RF3   G  0  1G ; }
RF4   K  0  1G ; } 
.MODEL DX D(Ron=1 Roff=1G Vfwd=.75)
.ends


.subckt EL34 A S G K ; screen edited!
* Mullard Data Book Apr 1962 
XV1 A S G K Tetrode
+params: MU=12.02 EX=1.169 KG1=380 KG2=840 KP=61.11 KVB=29.9 VCT=0.00 RGI=1000 CCG=15.0p cpg=1.0p CCP=8.0p
.ends

.subckt EL34_JJ A S G K ; screen edited!
* JJ Data Sheet 
XV1 A S G K Tetrode
+params: MU=11.55 EX=1.350 KG1=650.2 KG2=1360 KP=51.85 KVB=25.4 VCT=0.00 RGI=1000 CCG=15.0p cpg=1.0p CCP=8.0p
.ends

.subckt EL84 A S G K ; screen edited!
* Mullard Data Sheet AKA 7189 6BQ5 N709 
XV1 A S G K Tetrode
+params: MU=21.29 EX=1.240 KG1=425 KG2=1150 KP=111.04 KVB=17.9 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=5.1p
.ends

.subckt EL84_JJ A S G K ; screen edited!
* JJ Data Sheet AKA 6BQ5  
XV1 A S G K Tetrode
+params: MU=19.56 EX=1.350 KG1=640 KG2=1840 KP=131.34 KVB=17.5 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=5.1p
.ends

.subckt KT66 A S G K
* M-O Valve Co AKA Genalex 
XV1 A S G K Tetrode
+params: MU=11.68 EX=1.197 KG1=510.9 KG2=1500 KP=34.89 KVB=22.3 VCT=0.00 RGI=1000 CCG=16.0p cpg=2.3p CCP=10.0p
.ends

.subckt KT66_JJ A S G K
* JJ Data Sheet 
XV1 A S G K Tetrode
+params: MU=10.50 EX=1.314 KG1=866.5 KG2=1500 KP=36.12 KVB=25.3 VCT=0.00 RGI=1000 CCG=16.0p cpg=2.3p CCP=10.0p
.ends

.subckt KT77 A S G K
* The M-O Valve Co AKA Genalex 
XV1 A S G K Tetrode
+params: MU=12.49 EX=1.487 KG1=1058.5 KG2=1500 KP=56.64 KVB=19.4 VCT=0.00 RGI=1000 CCG=16.5p cpg=1.0p CCP=9.0p
.ends

.subckt KT77_JJ A S G K
* JJ Data Sheet 
XV1 A S G K Tetrode
+params: MU=13.27 EX=1.350 KG1=460.2 KG2=1500 KP=31.98 KVB=55.7 VCT=0.00 RGI=1000 CCG=16.5p cpg=1.0p CCP=9.0p
.ends

.subckt KT88 A S G K
* The M-O Valve Co AKA Genalex 
XV1 A S G K Tetrode
+params: MU=12.38 EX=1.246 KG1=340.4 KG2=1500 KP=26.48 KVB=36.5 VCT=0.00 RGI=1000 CCG=14.0p cpg=0.8p CCP=12.0p
.ends

.subckt KT88_JJ A S G K
* JJ Data Sheet 
XV1 A S G K Tetrode
+params: MU=12.43 EX=1.218 KG1=315.7 KG2=1500 KP=26.72 KVB=36.1 VCT=0.00 RGI=1000 CCG=14.0p cpg=0.8p CCP=12.0p
.ends

.subckt 6L6GC A S G K
XV1 A S G K Tetrode
+params: MU=9.88 EX=1.442 KG1=1686.6 KG2=1500 KP=30.98 KVB=19.4 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=6.5p
.ends

.subckt 6L6GC_JJ A S G K
* JJ Data sheet 
XV1 A S G K Tetrode
+params: MU=13.94 EX=1.063 KG1=320.2 KG2=1500 KP=33.20 KVB=29.6 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=6.5p
.ends

.subckt 6L6GB A S G K
* Sylvania
XV1 A S G K Tetrode
+params: MU=8.77 EX=1.265 KG1=1210.3 KP=47.50 KG2=1500 KVB=11.6 VCT=0.00 CCG=14P cpg=.85P CCP=12P RGI=1K
.ends

.subckt 6550 A S G K
XV1 A S G K Tetrode
+params: MU=8.61 EX=1.435 KG1=1066.6 KG2=1500 KP=39.55 KVB=20.5 VCT=0.00 RGI=1000 CCG=15.0p cpg=0.8p CCP=10.0p
.ends

.subckt 6550A A S G K
* GE Data sheet 1973 
XV1 A S G K Tetrode
+params: MU=10.81 EX=1.397 KG1=703.2 KG2=1500 KP=27.68 KVB=19.1 VCT=0.00 RGI=1000 CCG=15.0p cpg=0.8p CCP=10.0p
.ends

.subckt 5881 A S G K
* Tung-Sol Data Book 
XV1 A S G K Tetrode
+params: MU=8.35 EX=1.484 KG1=2507.1 KG2=1500 KP=53.86 KVB=14.4 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=6.5p
.ends

.subckt 6BQ5 A S G K
* Mullard Data Sheet AKA 7189 EL84 N709 
XV1 A S G K Tetrode
+params: MU=21.29 EX=1.240 KG1=401.7 KG2=1500 KP=111.04 KVB=17.9 VCT=0.00 RGI=1000 CCG=10.0p cpg=0.6p CCP=5.1p
.ends



*************************************
* Small Signal and Vary Mu Pentodes *
*************************************

.subckt EF80 A S G K ; screen edited!
* Philips data sheet AKA 6BX6
XV1 A S G K Tetrode2
+params: MU=49.11 EX=1.420 KG1=620 KG2=690 KP=375.96 KVB=42.9 VCT=0.50 RGI=100 CCG=2.6p cpg=0.007p CCP=3.3p
.ends

.subckt EF83 A S G K ; screen edited!
* Philips data sheet
XV1 A S G K Tetrode
+params: MU=12.01 EX=1.350 KG1=2800.0 KG2=3000 KP=35.24 KVB=39.1 VCT=0.00 RGI=2000 CCG=4.5p cpg=0.6p CCP=5.6p
.ends

.subckt EF85 A S G K ; variable mu pentode ; screen edited!
* Philips data sheet
XV1 A S G K Tetrode2
+params: MU=22.39 EX=1.350 KG1=1050 KG2=1350 KP=160.84 KVB=40.9 VCT=0.00 RGI=100 CCG=6.9p cpg=0.007p CCP=3.2p
.ends

.subckt EF86 A S G K ; screen edited!
* Philips data sheet AKA 6CF8 and 6267 Z729 EF806
XV1 A S G K Tetrode
+params: MU=34.90 EX=1.350 KG1=2648.1 KG2=4300 KP=222.06 KVB=4.7 VCT=0.00 RGI=2000 CCG=4.3p cpg=0.6p CCP=5.1p
.ends

.subckt EF89 A S G K ; variable mu pentode ; screen edited!
* Philips data sheet AKA 6DA6
XV1 A S G K Tetrode
+params: MU=30.52 EX=1.350 KG1=1110 KG2=460 KP=39.49 KVB=23.6 VCT=0.00 RGI=100 CCG=5.5p cpg=0.002p CCP=5.1p
.ends


********************************
* Triode small signal Pentodes *
********************************

.subckt 7199_pentode A S G K
* RCA 
XV1 A S G K Tetrode
+params: MU=97.92 EX=1.350 KG1=361.8 KG2=1500 KP=79.56 KVB=6.4 VCT=0.00 RGI=2000 CCG=5.7p cpg=0.6p CCP=2.5p
.ends

.subckt 6AN8_pentode A S G K
* Sylvania Data sheet 
XV1 A S G K Tetrode
+params: MU=47.04 EX=1.350 KG1=487.2 KG2=1500 KP=113.02 KVB=17.0 VCT=0.00 RGI=2000 CCG=5.7p cpg=0.6p CCP=2.5p
.ends

.subckt ECF80_pentode A S G K ; screen edited!
* Philips data sheet AKA 6BL8  
XV1 A S G K Tetrode
+params: MU=46.13 EX=1.350 KG1=730 KG2=720 KP=149.94 KVB=8.0 VCT=0.00 RGI=100 CCG=5.2p cpg=0.0025p CCP=3.4p
.ends

.subckt ECF82_pentode A S G K ; screen edited!
* Universal Vademecum (1960) AKA 6U8
XV1 A S G K Tetrode
+params: MU=37.97 EX=1.350 KG1=823 KG2=674 KP=90.97 KVB=20.1 VCT=0.00 RGI=100 CCG=5.0p cpg=0.007p CCP=3.5p
.ends

.subckt 6U8A_pentode A S G K ; screen edited!
* Universal Vademecum (1960) AKA 6U8
XV1 A S G K Tetrode
+params: MU=37.97 EX=1.350 KG1=823 KG2=674 KP=90.97 KVB=20.1 VCT=0.00 RGI=100 CCG=5.0p cpg=0.007p CCP=3.5p
.ends

.subckt ECF83_pentode A S G K ; screen edited!
* Universal Vademecum (1960) 
XV1 A S G K Tetrode
+params: MU=12.24 EX=1.350 KG1=2401.0 KG2=1740 KP=27.36 KVB=23.5 VCT=0.00 RGI=100 CCG=4.1p cpg=0.025p CCP=4.1p
.ends

.subckt ECF86_pentode
* Sylvania Technical Manual AKA 6HG8 
XV1 A S G K Tetrode
+params: MU=64.17 EX=1.350 KG1=328.7 KG2=1500 KP=394.31 KVB=26.0 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends


**************************
* Triode Output Pentodes *
**************************

.subckt ECL80_pentode A S G K
* Philips Data book 1951 AKA 6AB8 
XV1 A S G K Tetrode
+params: MU=39.01 EX=0.925 KG1=228.9 KG2=1500 KP=50.26 KVB=21.2 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL81_pentode A S G K
* universal vademecum (1960) 
XV1 A S G K Tetrode
+params: MU=17.51 EX=1.350 KG1=590.8 KG2=1500 KP=209.03 KVB=32.5 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL82_pentode A S G K
* Philips Data Book 17-02-1956 AKA 6BM8 
XV1 A S G K Tetrode
+params: MU=12.19 EX=1.350 KG1=522.0 KG2=1500 KP=38.60 KVB=25.8 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL83_pentode A S G K
* Mullard Data Book 1960 
XV1 A S G K Tetrode
+params: MU=10.96 EX=1.350 KG1=1249.7 KG2=1500 KP=54.82 KVB=14.5 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL84_pentode A S G K
* Philips Data Book sept 1968 AKA 6DX8 
XV1 A S G K Tetrode
+params: MU=43.66 EX=1.350 KG1=344.3 KG2=1500 KP=201.06 KVB=26.0 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL85_pentode A S G K
* Philips Data Book Jan 1960 AKA 6GV8 
XV1 A S G K Tetrode
+params: MU=9.35 EX=1.350 KG1=556.4 KG2=1500 KP=35.28 KVB=21.3 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends

.subckt ECL86_pentode A S G K
* Philips Data Book Jan 1970 AKA 6GW8 
XV1 A S G K Tetrode
+params: MU=23.15 EX=1.350 KG1=479.1 KG2=1500 KP=128.94 KVB=36.0 VCT=0.00 RGI=2000 CCG=6.7p cpg=0.6p CCP=4.1p
.ends



********************************************
* Use this part for where is wired as triode
* (screen to anode). In this implementation
* screen grid has no effect but is just 
* included here to make the schematic
* drawing complete showing all terminals.
* Note in this case param kg2 is ignored.
********************************************

.subckt TetrodeT A S G K ; base generic = KT66
+params: MU=8 EX=1.4 KG1=1050 KG2=0 KP=80 KVB=22.3 VCT=0.00 RGI=1000 CCG=16.0p cpg=2.3p CCP=10.0p

RE1   E1 0  1MEG ; dummy so node E1 has two connections
Ee1   E1 0  Value {(V(A,K)/{kP}) * log(1 + exp({kP} * (1/{mu} + (V(G,K)+VCT)/sqrt({kVB} + pwr(V(A,K),2)))))}
GIP   A  K  Value {(pwr(V(E1),EX) + pwrs(V(E1),EX))/KG1} ; Norman Koren's

R1    G  5  {rgi} ; for grid forward current
D1    5  K  DX ; for grid diode action
CM1   G  K  {ccg}
CM2   A  G  {cpg}
CM3   A  K  {ccp}
RF1   A  0  1G
RF2   S  0  1G
RF3   G  0  1G ; prevent floating nodes
RF4   K  0  1G
.MODEL DX D(IS=1N RS=1)
.ends


.subckt EL34_at A S G K ; wired as triode
XV1 A S G K TetrodeT
+params: mu=11.17 ex=1.48 kg1=597 kp=40.5 kvb=24.6 cpg=1.1p ccg=15p ccp=8.5p rgi=1000
.ends

.subckt KT66_at A S G K ; wired as triode
* Marconi datasheet
XV1 A S G K TetrodeT
+params: MU=8 EX=1.4 KG1=1050 KG2=1500 KP=80 KVB=22.3 VCT=0.00 RGI=1000 CCG=16.0p cpg=2.3p CCP=10.0p
.ends

.subckt ECF82_at A S G K ; pentode wired as triode
* graph by Tom Schlangen
XV1 A S G K TetrodeT
+params: MU=35 EX=1.3 KG1=670 KG2=1500 KP=200 KVB=20.1 VCT=0.00 RGI=2000 CCG=5.7p cpg=0.6p CCP=4.1p
.ends

.subckt 6U8A_at A S G K ; wired as triode
* Universal Vademecum (1960) AKA 6U8
XV1 A S G K TetrodeT
+params: MU=37.97 EX=1.350 KG1=849.8 KG2=1500 KP=90.97 KVB=20.1 VCT=0.00 RGI=2000 CCG=5.7p cpg=0.6p CCP=4.1p
.ends

.subckt 6V6 A S G K
* loosely based on EL84, with some tweaks
XV1 A S G K Tetrode
+params: MU=13.49 EX=1.24 KG1=401.7 KG2=1500 KP=111.04 KVB=17.9 VCT=0.00 RGI=1000 CCG=4.5p cpg=0.7p CCP=7.5p
.ends


